Online File

How to use this page

---

Rick Aster: Professional SAS Programming Shortcuts: Contents

Chapter 76
Program
Arithmetic

---

OPTIONS MISSING=' ';
DATA _NULL_;
   WINDOW Math
       ROWS=10 COLUMNS=40 IROW=7 ICOLUMN=16
       GROUP=MENU
       #1 @2 '1   Add two numbers'
       #2 @2 '2   Multiply two numbers'
       #4 @2 '.Q  Quit'
       GROUP=ADD
       #1 @2 'Enter two numbers to add.'
       #3 @2 TERM1 BEST15. ATTR=REV_VIDEO
       +1 '+'
       +1 TERM2 BEST15. ATTR=REV_VIDEO
       GROUP=SUM
       #1 @2 'The sum is ' SUM BEST16. PROTECT=YES
       #3 @2 'Press ENTER to continue.'
       GROUP=MULTIPLY
       #1 @2 'Enter two numbers to multiply.'
       #3 @2 FACTOR1 BEST15. ATTR=REV_VIDEO
       +1 'x'
       +1 FACTOR2 BEST15. ATTR=REV_VIDEO
       GROUP=PRODUCT
       #1 @2 'The product is ' PRODUCT BEST18. PROTECT=YES
       #3 @2 'Press ENTER to continue.'
       ;

   DISPLAY MATH.MENU BLANK; * Menu;
   SELECT(SCAN(COMPRESS(UPCASE(_CMD_)), 1, ';'));
      WHEN('1') DO;
         DISPLAY MATH.ADD BLANK; * Addition dialog box;
         SUM = SUM(0, TERM1, TERM2);
         DISPLAY MATH.SUM BLANK; * Sum dialog box;
         END;
      WHEN('2') DO;
         DISPLAY MATH.MULTIPLY BLANK; * Multiply dialog box;
         IF FACTOR1 AND FACTOR2 THEN PRODUCT = FACTOR1*FACTOR2;
         ELSE PRODUCT = 0;
         DISPLAY MATH.PRODUCT BLANK; * Product dialog box;
         END;
      WHEN('.Q') STOP;
      OTHERWISE DO;
         IF _CMD_ = ' ' THEN _MSG_ = 'Enter option on command line.';
         ELSE _MSG_ = 'Option not recognized.';
         END;
      END;
RUN;